VB.NET Невозможно вернуть список на основе уникальных значений

Используя VB.NET, я получаю список объектов. Из этого списка объектов мне нужно удалить дублирующиеся наборы данных, чтобы список был уникальным по всем столбцам. Читая на StackOverflow, общее мнение состоит в том, чтобы использовать GroupBy, за которым следует Select, однако каждый раз, когда я пытаюсь это сделать, возвращается вся коллекция.

В данном примере я ожидаю, что количество в uniqueData будет равно 3, но оно остается равным 4. dataSet1 и dataSet2 должны рассматриваться как дубликаты друг друга.

Module Program
    Sub Main(args As String())
        Dim data As New PersonCollection With {.PersonCollection = New List(Of PersonInfo)}
        Dim dataSet1 As New PersonInfo With {.FirstName = "Боб", .LastName = "Смит", .Rating = 10}
        Dim dataSet2 As New PersonInfo With {.FirstName = "Джон", .LastName = "Херт", .Rating = 20}
        Dim dataSet3 As New PersonInfo With {.FirstName = "Боб", .LastName = "Смит", .Rating = 30}
        Dim dataSet4 As New PersonInfo With {.FirstName = "Боб", .LastName = "Смит", .Rating = 10}
        data.PersonCollection.Add(dataSet1)
        data.PersonCollection.Add(dataSet2)
        data.PersonCollection.Add(dataSet3)
        data.PersonCollection.Add(dataSet4)

        Dim uniqueData = data.PersonCollection.GroupBy(Function(x) New With {x.FirstName, x.LastName, x.Rating}).Select(Function(x) x.First).ToList()

        Console.ReadLine()
    End Sub


    Private Class PersonCollection
        Property PersonCollection As List(Of PersonInfo)
    End Class

    Private Class PersonInfo
        Property FirstName As String
        Property LastName As String
        Property Rating As Integer
    End Class
End Module

Это работает с кортежами:

Module Program
    Sub Main(args As String())
        Dim data As New PersonCollection With {.PersonCollection = New List(Of PersonInfo)}
        Dim dataSet1 As New PersonInfo With {.FirstName = "Боб", .LastName = "Смит", .Rating = 10}
        Dim dataSet2 As New PersonInfo With {.FirstName = "Джон", .LastName = "Херт", .Rating = 20}
        Dim dataSet3 As New PersonInfo With {.FirstName = "Боб", .LastName = "Смит", .Rating = 30}
        Dim dataSet4 As New PersonInfo With {.FirstName = "Боб", .LastName = "Смит", .Rating = 10}
        data.PersonCollection.Add(dataSet1)
        data.PersonCollection.Add(dataSet2)
        data.PersonCollection.Add(dataSet3)
        data.PersonCollection.Add(dataSet4)

        Dim uniqueData = data.PersonCollection _
            .GroupBy(Function(x) New Tuple(Of String, String, Integer)(
                x.FirstName, x.LastName, x.Rating)) _
            .Select(Function(x) x.First).ToList()
        Console.ReadLine()
    End Sub


    Private Class PersonCollection
        Property PersonCollection As List(Of PersonInfo)
    End Class

    Private Class PersonInfo
        Property FirstName As String
        Property LastName As String
        Property Rating As Integer
    End Class
End Module

Но лучше использовать Comparer:

Module Program
    Sub Main(args As String())
        Dim data As New PersonCollection With {.PersonCollection = New List(Of PersonInfo)}
        Dim dataSet1 As New PersonInfo With {.FirstName = "Боб", .LastName = "Смит", .Rating = 10}
        Dim dataSet2 As New PersonInfo With {.FirstName = "Джон", .LastName = "Херт", .Rating = 20}
        Dim dataSet3 As New PersonInfo With {.FirstName = "Боб", .LastName = "Смит", .Rating = 30}
        Dim dataSet4 As New PersonInfo With {.FirstName = "Боб", .LastName = "Смит", .Rating = 10}
        data.PersonCollection.Add(dataSet1)
        data.PersonCollection.Add(dataSet2)
        data.PersonCollection.Add(dataSet3)
        data.PersonCollection.Add(dataSet4)

        Dim comparer As New PersonInfoComparer
        Dim uniqueData = data.PersonCollection.Distinct(comparer).ToList

        Console.ReadLine()
    End Sub

    Private Class PersonCollection
        Property PersonCollection As List(Of PersonInfo)
    End Class

    Private Class PersonInfo
        Property FirstName As String
        Property LastName As String
        Property Rating As Integer
    End Class

    Private Class PersonInfoComparer : Inherits EqualityComparer(Of PersonInfo)

        Public Overrides Function Equals(x As PersonInfo, y As PersonInfo) As Boolean
            Return x.FirstName.Equals(y.FirstName) _
                AndAlso x.LastName.Equals(y.LastName) _
                AndAlso x.Rating.Equals(y.Rating)
        End Function

        Public Overrides Function GetHashCode(obj As PersonInfo) As Integer
#If NETSTANDARD2_0_OR_GREATER Or NETCOREAPP2_1_OR_GREATER Then
            Return HashCode.Combine(obj.FirstName, obj.LastName, obj.Rating)
#Else
            Return obj.FirstName.GetHashCode() _
                Xor obj.LastName.GetHashCode() _
                Xor obj.Rating.GetHashCode()
#End If
        End Function

    End Class

End Module

Попробуйте использовать кортеж вместо этого, поскольку он имеет семантику значений в отличие от типа анонимного класса, который имеет семантику ссылок. Т.е., два объекта сравниваются по ссылке, а не по их полям или свойствам.

.GroupBy(Function(x) (x.FirstName, x.LastName, x.Rating))

Обратите внимание, что синтаксис New With {x.FirstName ... } работает с О/R маппером, потому что затем это преобразуется в SQL, и различие между семантикой значений и семантикой ссылок больше не применяется.

Другим решением является объявление свойств анонимного типа как Ключевых свойств.

.GroupBy(Function(x) New With {Key x.FirstName, Key x.LastName, Key x.Rating})

Но кортежи гораздо проще.

Мы можем немного упростить запрос, используя DistinctBy вместо GroupBy, за которым следует Select:

Dim uniqueData = data.PersonCollection _
    .DistinctBy(Function(x) (x.FirstName, x.LastName, x.Rating)) _
    .ToList()