Как использовать AND и OR вместе в программе awk?

У меня есть файл с двумя колонками, например:

$ cat data
a4 b1
a4 c2
a4 b4
z4 c2

Я хочу сопоставить обе колонки так, чтобы
если (column1 = a4 and column2 = b1) ИЛИ (column1 = a4 and column2 = c2)
то вывод в колонке3 должен быть

(ЖЕЛАЕМЫЙ ВЫВОД):

a4 b1 matched
a4 c2 matched
a4 b4 -
z4 c2 -

Поэтому я попытался внедрить свою логику в однострочный awk:

$ awk '{print $1, $2, (($1 = a4 && $2 = b1) || ($1 = a4 && $2 = c2) ? "a4-matched" : "-")}' data

И я получаю – для всей колонки3, я думаю, у меня синтаксическая ошибка в awk, или что-то другое отсутствует — ниже результат:

a4 b1 -
a4 c2 -
a4 b4 -
z4 c2 -

Вы были почти правы, но, похоже, вы допустили синтаксическую ошибку: $1=a4 не проверяет, равна ли первая колонка a4, а присваивает содержимое переменной awk a4 (которая не определена и поэтому пуста) первой колонке, перезаписывая ее содержимое (которое вы уже напечатали, так что вы этого не заметили) и также оценивается как “ложь”, потому что неинициализированная переменная оценивается как “ложь”. То же самое верно и для ваших других сравнений. Поэтому вы никогда не получаете условие “сопоставлено” как “истина”.

С (несколькими) необходимыми исправлениями программа будет выглядеть следующим образом:

awk '{if (($1=="a4" && $2=="b1") || ($1=="a4" && $2=="c2")) $3="matched"; else $3="-"} 1' data.txt 

Она работает следующим образом:

• Для каждой строки она проверяет, соблюдаются ли условия, которые вы упоминаете, и добавляет третью колонку в строку, устанавливая $3 либо в -, либо в matched.
• Затем она печатает текущую строку, включая любые внесенные изменения. Это значение по-видимому, бесполезного 1 вне блока правил – awk печатает текущую строку, включая все предыдущие изменения, если он встречает условие, которое оценивается как “истина” вне правила.

Обратите внимание, что приведенная выше программа написана явно для удобства понимания и для демонстрации этого момента. В вашем случае ее можно сократить, так как условие на $1 одинаково для обоих “разрешенных” случаев $2:

awk '{if ($1=="a4" && ($2=="b1" || $2=="c2")) $3="matched"; else $3="-"} 1' data.txt

Также обратите внимание, что изменение любого поля приведет к восстановлению awk строки из ее отдельных полей с использованием разделителя полей вывода (по умолчанию один пробел), поэтому, если исходные поля были разделены более чем одним пробелом, оригинальное форматирование будет испорчено. Если это проблема, вы должны использовать стратегию “добавления”, которую вы уже выбрали в попытке, хотя вы должны тогда печатать $0, ( ваша условная строка ), а не $1, $2, ( ваша условная строка ).

$ awk '{print $0, ($1=="a4" && ($2 ~ /^(b1|c2)$/) ? "matched" : "-")}' file
a4 b1 matched
a4 c2 matched
a4 b4 -
z4 c2 -

Вам не нужно дважды проверять $1, проверьте его один раз, так как это одно и то же условие в обоих случаях, и сделайте несколько проверок $2 для различных вариантов. Обратите внимание, что присвоение новых полей приведет к перестройке $0 с использованием значения по умолчанию OFS (один пробел), что приведет к сжатию последовательных пробелов в один, если в вашем входе были такие.

awk '{ print $0, ($1=="a4" && ($2=="b1" || $2=="c2")?"matched":"-") }' infile

Вы также можете просто использовать оператор сравнения меньше (<) вместо логических, таких как ИЛИ (||) / И (&&), как только вы отменили одно из условий, так как вы на самом деле не экономите столько времени, используя короткое замыкание для относительно простых логических выражений:

echo 'a4 b1   
a4 c2
a4 b4
z4 c2' | 

awk '$3 = ($2 !~ /^(b1|c2)$/) < ($1 == "a4") ? "matched" : "-"'

a4 b1 matched
a4 c2 matched
a4 b4 -
z4 c2 -