Макрос VBA для Outlook, чтобы пересылать вложение электронной почты, но удалить текст сообщения.

Я пытаюсь добавить пользовательское действие к правилу в Outlook, при котором сообщение автоматически пересылается, а вложение остаётся, но оригинальный текст сообщения удаляется.

Мне нужно написать код для части ‘очистки содержимого’. На данный момент у меня есть следующее:

Public Sub MyMacro(msg As MailItem)
  Dim strID As String
  Dim olNS As NameSpace
  Dim olMail As MailItem

  strID = msg.EntryID
  Set olNS = Application.GetNamespace("MAPI")
  Set olMail = olNS.GetItemFromID(strID)

  With olMail.HTMLBody = " "
  End With

  Set olMail = Nothing
  Set olNS = Nothing
End Function

После .HTMLBody я не могу удалить ничего.

Правка: Добавил фактическое требование, скрытое в комментарии. “Мне нужно, чтобы оригинальное содержимое электронной почты было удалено, включая информацию о том, от кого оно. В общем, чтобы это выглядело как совершенно новое электронное письмо.”

Оператор “With” позволяет вам ссылаться на несколько свойств объекта (в данном случае olMail) в блоке.

Поскольку вы устанавливаете только одно свойство, нет необходимости использовать блок “With”. Попробуйте без операторов “With/End With”, просто используя olMail.HTMLBody = "", и удалите строку End With.

Не вижу, как код может что-то сделать с учётом оператора with и

Public Sub и End Function

Примечание: Код не тестировался. В нём могут быть опечатки и другие проблемы.

Public Sub MyMacro(msg As MailItem)
  Dim strID As String
  Dim olNS As NameSpace
  Dim olMail As MailItem

  Dim olMailFwd as Mailitem

  strID = msg.EntryID
  Set olNS = Application.GetNamespace("MAPI")
  Set olMail = olNS.GetItemFromID(strID)

  'With olMail
  '  .HTMLBody = " "
  'End With

  Set olMailFwd = olMail.Forward

  With olMailFwd
      .HTMLBody = ""
      .subject = olMail.subject ' Нет FW:
      .To = "[email protected]"
  end with

  olMailFwd.display
  ' после первоначального тестирования изменить на
  ' olMailFwd.Send

  Set olMailFwd = Nothing
  Set olMail = Nothing
  Set olNS = Nothing

End Sub

Если только у вас нет ещё чего-то, чем вы не поделились.

Public Sub MyMacro(msg As MailItem)

  Dim olMailFwd as Mailitem

  Set olMailFwd = msg.Forward

  With olMailFwd
      .HTMLBody = ""
      .subject = msg.subject ' Нет FW:
      .To = "[email protected]"
  end with

  olMailFwd.display
  ' после первоначального тестирования изменить на
  ' olMailFwd.Send

  Set olMailFwd = Nothing

End Sub