Альтернатива Whereisit для Mac

Я ищу альтернативу Whereisit для Windows, чтобы индексировать мои файлы и папки по типу файла и иметь возможность просматривать снимок индексированных файлов позже.

Не мог бы кто-нибудь предложить альтернативу Whereisit для Mac?

Whereisit позволяет индексировать диски и сохранять индекс для последующего использования. Индексированный файл позволяет просматривать диски так, как если бы вы просматривали их обычно. Файлы не сохраняются, только имена файлов и миниатюры хранятся в виде списка директорий.

На Mac есть командная строка terminal command whereis, которая показывает расположение файла. whereis python дает расположение python. Также which python показывает текущую действующую версию python.

Вот AppleScript, который рекурсивно перечисляет файлы и папки с параметрами. Источник

property script_name : "List Folder Contents"
property script_description : "Этот скрипт перечислит содержимое папки, возвращая полные пути в виде строк и ограничивая список конкретными типами файлов. Скрипт также может обрабатывать подпапки (рекурсия)."

set the_folder to (choose folder with prompt "Выберите папку для перечисления:") as Unicode text
set file_types to {} --типы файлов, установите {} и inc_folders в true, чтобы вернуть только папки; типы файлов - это 4-символьные коды, такие как "osas" или "TEXT"

set with_subfolders to my get_boolean("Искать в подпапках?", {"Нет", "Да"})
if with_subfolders = "user cancelled" then return

set inc_folders to my get_boolean("Включить папки в список? (Если вы хотите только имена файлов, а не имена папок, выберите \"Нет\".)", {"Нет", "Да"})
if inc_folders = "user cancelled" then return

set use_posix_path to my get_boolean("Возвращать пути как HFS (Mac-стиль) или POSIX (UNIX-стиль)?", {"HFS", "POSIX"})
if use_posix_path = "user cancelled" then return

set return_as_string to my get_boolean("Возвращать результаты как список AppleScript или строку с каждым файлом на отдельной строке?", {"Список", "Строка"})
if return_as_string = "user cancelled" then return

set add_to_clipboard to my get_boolean("Скопировать результаты в буфер обмена?", {"Нет", "Да"})
if add_to_clipboard = "user cancelled" then return

set the_files to get_folder_list(the_folder, file_types, with_subfolders, inc_folders, use_posix_path)

if return_as_string then
    tell (a reference to my text item delimiters)
        set {old_tid, contents} to {contents, return}
        set {the_files_string, contents} to {the_files as Unicode text, old_tid}
    end tell
    copy the_files_string to the_files
end if

if add_to_clipboard then
    if not return_as_string then
        copy the_files to the_files_string
        repeat with i from 1 to (count the_files_string)
            set item i of the_files_string to ("\"" & item i of the_files_string & "\", ")
        end repeat
        set the_files_string to ("{" & (text 1 thru -3 of (the_files_string as Unicode text)) & "}")
    end if
    set the clipboard to the_files_string
end if
beep
return the_files

on get_folder_list(the_folder, file_types, with_subfolders, inc_folders, use_posix_path)
    set the_files to {}
    tell application "Finder" to set folder_list to items of folder the_folder
    repeat with new_file in folder_list
        try
            set temp_file_type to file type of new_file
        on error
            set temp_file_type to "fold"
        end try
        if file_types contains temp_file_type or file_types = {} then
            if use_posix_path then
                set the_files to the_files & {POSIX path of (new_file as Unicode text)}
            else
                set the_files to the_files & {new_file as Unicode text}
            end if
        end if
        if temp_file_type = "fold" then
            if inc_folders and file_types ≠ {} then
                if use_posix_path then
                    set the_files to the_files & {POSIX path of (new_file as Unicode text)}
                else
                    set the_files to the_files & {new_file as Unicode text}
                end if
            end if
            if with_subfolders then set the_files to the_files & my get_folder_list((new_file as Unicode text), file_types, with_subfolders, inc_folders, use_posix_path)
        end if
    end repeat
    return the_files
end get_folder_list

on get_boolean(m, b)
    try
        return (button returned of (display dialog m buttons ({"Отмена"} & b) default button 3 with icon 1) = (b's item 2))
    on error
        return "user cancelled"
    end try
end get_boolean

Скорее всего, он уже установлен:

    ОПИСАНИЕ
         Программа locate ищет в базе данных все имена путей, которые соответствуют
         указанному шаблону. База данных пересчитывается периодически (обычно
         раз в неделю или день) и содержит имена путей всех файлов, которые
         доступны публично.
...
     Программа locate может не отобразить некоторые файлы, которые присутствуют, или
     может показать файлы, которые были удалены из системы. Это произошло потому, что
     locate отображает только файлы, которые присутствуют в базе данных, которая
     обычно обновляется раз в неделю
     с помощью задания /System/Library/LaunchDaemons/com.apple.locate.plist. Используйте find(1), чтобы
     найти файлы более временного характера.

–вырезка из man locate.

На системе вроде:

OS, ker|rel, machine: Apple/BSD, Darwin 17.3.0, x86_64
Distribution        : macOS 10.13.2 (17C88), High Sierra
bash GNU bash 3.2.57
locate - ( /usr/bin/locate, 2017-10-25 )

Обратите внимание, что locate отображает совпадения с полным путем, поэтому вы можете получить гораздо больше вывода, чем ожидали. Я обычно перенаправляю вывод в less или grep.

Например:

$ locate a.out

выдает:

/Applications/Xcode.app/Contents/Developer/Toolchains/XcodeDefault.xctoolchain/usr/share/man/man5/a.out.5
/Library/Developer/CommandLineTools/usr/share/man/man5/a.out.5
/Users/drl/try/confidence/lct-c/a.out
/Users/test1/try/confidence/lct-c/a.out
/usr/local/Homebrew/Library/Homebrew/test/support/fixtures/mach/a.out

Для более длинного списка его необходимо будет обрезать, просматривать с помощью программы просмотра и т. д.

С наилучшими пожеланиями … всего доброго, drl