Горячие клавиши в неанглоязычной версии Microsoft Office

У меня есть большая проблема с португальской версией MS Office 2007 и 2010.

Стандартные сочетания клавиш, которые используются в любом обычном приложении, изменены.
Некоторые сочетания клавиш, которые не работают: Ctrl+s (сохранить), Ctrl+f (поиск) и Ctrl+a (выбрать все).

Я хочу настроить их так, чтобы использовать сочетания клавиш английской версии.

Существует опция, позволяющая настраивать каждое сочетание клавиш отдельно. Более того, я должен настраивать для каждого приложения, если я настраиваю в Word, я должен настраивать снова в Excel.

Как использовать сочетания клавиш английской версии MS Office независимо от языка Office?

Спасибо

Я почти уверен, что в приложениях MS Office нет встроенного способа изменить сочетания клавиш.

Однако вы можете использовать AutoHotkey для этой цели.

Скрипт

^a::
^f::
^s::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a")
           SendPlay, ^e
       if(A_ThisHotKey = "^f")
           SendPlay, ^b
       if(A_ThisHotKey = "^s")
           SendPlay, ^g
    }
    else
        SendPlay, %A_ThisHotKey%
return

Как это работает

• ^a:: задает одно из горячих клавиш, которые запускают скрипт до инструкции return, где ^ обозначает клавишу Ctrl.

• WinGet, Process, ProcessName, A сохраняет имя процесса активного (A) окна в переменной Process.

• if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$")) {...} else ... проверяет, соответствует ли Process регулярному выражению, т.е. соответствует ли он одной из строк WINWORD.EXE или EXCEL.EXE.

  • Если да, выполняется первый блок.

    • if(A_ThisHotKey = "^a") проверяет, является ли нажатой горячей клавишей Ctrl + A.

      Если это так, он имитирует комбинацию клавиш Ctrl + E, которая является португальским сочетанием клавиш для выбора всего¹.

  • В противном случае SendPlay, %A_ThisHotKey% имитирует сочетание клавиш, которое было изначально нажато.

    Таким образом, другие приложения продолжают вести себя так, как и должны.

Как использовать

1. Скачайте и установите последнюю версию AutoHotkey.

2. Сохраните приведенный выше скрипт как ms-office.ahk, используя ваш любимый текстовый редактор.

3. Дважды щелкните файл, чтобы запустить скрипт.

4. Если хотите, скопируйте скрипт (или ссылку на него) в папку Автозагрузка.

5. Чтобы добавить дополнительные приложения MS Office, просто измените регулярное выражение.

   Чтобы добавить PowerPoint, например, замените (WINWORD|EXCEL) на (WINWORD|EXCEL|POWERPNT).

6. Чтобы добавить дополнительные горячие клавиши, вам нужно изменить две части скрипта.

   Чтобы добавить Ctrl + O (Открыть…), добавьте строку ^o:: в список в самом верху, добавьте эти строки внутри блока if:

   if(A_ThisHotKey = "^o")
       SendPlay, ^a
   

¹ По крайней мере, я думаю, что это так. Я взял сочетания клавиш из своей испанской версии MS Office. Настройте при необходимости.

На основе предыдущего ответа, несколько дополнительных сочетаний клавиш (могли бы быть добавлены к предыдущему ответу):

^a::
^f::
^s::
^w::
^n::
^u::
^d::
^r::
^b::
^i::
^k::
^g::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a") ;выбрать диапазон
           SendPlay, ^e
       if(A_ThisHotKey = "^f") ;поиск
           SendPlay, ^b
       if(A_ThisHotKey = "^s") ;сохранить
           SendPlay, ^g
       if(A_ThisHotKey = "^w") ;закрыть
           SendPlay, ^r
       if(A_ThisHotKey = "^n") ;новая книга
           SendPlay, ^u
       if(A_ThisHotKey = "^u") ;подчеркнуть
           SendPlay, ^s
       if(A_ThisHotKey = "^b") ;жирный
           SendPlay, ^n
       if(A_ThisHotKey = "^i") ;курсив
           SendPlay, ^k
       if(A_ThisHotKey = "^d") ;заполнить вниз
           SendPlay, ^j
       if(A_ThisHotKey = "^r") ;заполнить вправо
           SendPlay, ^d
       if(A_ThisHotKey = "^k") ;гиперссылка
           SendPlay, ^!k
       if(A_ThisHotKey = "^g") ;перейти
           SendPlay, ^i
    }
    else
        SendPlay, %A_ThisHotKey%
return

Этот вопрос уже 8 лет. С тех пор появилась более простая альтернатива, так как Microsoft выпустила языковые пакеты для Office бесплатно.

Примечание: хотя это простой и чистый подход, у него есть побочный эффект — интерфейс Office (меню и диалоговые окна) также меняется на английский.

Вы можете скачать языковые пакеты для Office 2016, Office 2013 и Office 2010 по ссылке. Скачайте и установите языковой пакет для английского, затем выполните шаги, описанные на странице загрузки, чтобы настроить язык отображения MS Office. После перезагрузки английские сочетания клавиш должны вступить в силу.

Примечание: изначально у меня было несколько ошибок после установки языкового пакета. Это потому, что я установил 64-разрядный языковой пакет поверх моего 32-разрядного Office. После исправления проблемы мой MS Office работает, как ожидалось.

Сокращенная версия скрипта AutoHotkey в качестве примера переназначения CTRL+B на CTRL+SHIFT+F и CTRL+I на CTRL+SHIFT+K (немецкие сочетания клавиш) в Word, Excel, Power Point.
Не блокирует отправку других сочетаний, когда клавиша CTRL не отпущена.

#If WinActive("ahk_class OpusApp") || WinActive("ahk_class XLMAIN") || WinActive("ahk_class PPTFrameClass")
^b::^+f
^i::^+k