Изменение стиля курсора в зависимости от режима в zsh и vim

Я использую vi-mode в oh-my-zsh с af-magic темой.

Я хочу, чтобы стиль курсора показывал, нахожусь ли я в нормальном режиме (блок) или в режиме вставки (луч), как в zsh, так и в vim.

Вот, что у меня есть на данный момент:

В моем ~/.zshrc:

    # vim mode config
    # ---------------

    # Activate vim mode.
    bindkey -v

    # Remove mode switching delay.
    KEYTIMEOUT=5

    # Change cursor shape for different vi modes.
    function zle-keymap-select {
      if [[ ${KEYMAP} == vicmd ]] ||
         [[ $1 = 'block' ]]; then
        echo -ne '\e[1 q'

      elif [[ ${KEYMAP} == main ]] ||
           [[ ${KEYMAP} == viins ]] ||
           [[ ${KEYMAP} = '' ]] ||
           [[ $1 = 'beam' ]]; then
        echo -ne '\e[5 q'
      fi
    }
    zle -N zle-keymap-select

    # Use beam shape cursor on startup.
    echo -ne '\e[5 q'

    # Use beam shape cursor for each new prompt.
    preexec() {
       echo -ne '\e[5 q'
    }

Как найдено здесь.

В vim я использую Vundle и terminus.

С этими конфигурациями, как zsh, так и vim работают так, как должны, когда рассматриваются независимо. Однако, когда я захожу в vim из zsh в режиме вставки, vim начинает в нормальном режиме (как и должно быть), но все еще показывает курсор в виде луча. Аналогично, когда я выхожу из vim, я возвращаюсь в zsh в режиме вставки, но курсор остается в виде блока (так как последний режим в vim был нормальным).

Когда после этого я переключаю режимы в первый раз (в обоих zsh и vim), курсор снова ведет себя как следует.

Как я могу заставить их показывать правильный курсор после входа и выхода из vim?

Я пытался добавить

    autocmd VimEnter * stopinsert
    autocmd VimLeave * startinsert

в мой ~.vimrc, но это не влияет на курсор.

Я думаю, лучше использовать precmd() вместо preexec():

# .zshrc

_fix_cursor() {
   echo -ne '\e[5 q'
}

precmd_functions+=(_fix_cursor)

Таким образом:

• вам не нужно изменять .vimrc
• курсор также исправляется при создании нового приглашения без выполнения команды
• вам не нужно дважды писать echo -ne '\e[5 q' в вашем .zshrc.

Это идеально работает для меня, взято отсюда: https://gist.github.com/LukeSmithxyz/e62f26e55ea8b0ed41a65912fbebbe52

# vi mode
bindkey -v
export KEYTIMEOUT=1

# Change cursor shape for different vi modes.
function zle-keymap-select {
  if [[ ${KEYMAP} == vicmd ]] ||
     [[ $1 = 'block' ]]; then
    echo -ne '\e[1 q'
  elif [[ ${KEYMAP} == main ]] ||
       [[ ${KEYMAP} == viins ]] ||
       [[ ${KEYMAP} = '' ]] ||
       [[ $1 = 'beam' ]]; then
    echo -ne '\e[5 q'
  fi
}
zle -N zle-keymap-select
zle-line-init() {
    zle -K viins # initiate `vi insert` as keymap (can be removed if `bindkey -V` has been set elsewhere)
    echo -ne "\e[5 q"
}
zle -N zle-line-init
echo -ne '\e[5 q' # Use beam shape cursor on startup.
preexec() { echo -ne '\e[5 q' ;} # Use beam shape cursor for each new prompt.

Вы можете настроить тип курсора, который вы хотите (мигающий или нет, |, прямоугольник или _), изменяя числа в следующих последовательностях \e[5 q (5 для луча, 1 для блока) следующим образом:

Установить стиль курсора (DECSCUSR), VT520.
0  ⇒  мигающий блок.
1  ⇒  мигающий блок (по умолчанию).
2  ⇒  стабильный блок.
3  ⇒  мигающее подчеркивание.
4  ⇒  стабильное подчеркивание.
5  ⇒  мигающий луч, xterm.
6  ⇒  стабильный луч, xterm.

Просто добавьте строку:

export VI_MODE_SET_CURSOR=true

в ваш ~/.zshrc.
Это упоминается в обсуждении вопроса #9570.

Я нашел решение:

Я поместил это в мой ~/.vimrc:

autocmd VimEnter * silent exec "! echo -ne '\e[1 q'"
autocmd VimLeave * silent exec "! echo -ne '\e[5 q'" 

Самый простой способ установить стиль курсора:

setopt vi
KEYTIMEOUT=1
# change cursor shape in vi mode
zle-keymap-select () {
    if [[ $KEYMAP == vicmd ]]; then
        # режим команд для vi
        echo -ne "\e[2 q"
    else
        # режим вставки для vi
        echo -ne "\e[5 q"
    fi
}
precmd_functions+=(zle-keymap-select)
zle -N zle-keymap-select

Вы также можете использовать zle-line-init()

zle-line-init() {
    zle -K viins # инициализация `vi insert` как keymap (можно удалить, если `bindkey -V` был установлен в другом месте)
    echo -ne "\e[5 q"
}

Я думаю, что эта проблема лучше решается с помощью этого, чем precmd() или preexec() так как обе функции предназначены для выполнения команд, вместо положения фиксации.

Следующий скрипт работает для меня. Он меняет курсор каждый раз после запуска/выхода из программы.

function _set_cursor() {
    if [[ $TMUX = '' ]]; then
      echo -ne $1
    else
      echo -ne "\ePtmux;\e\e$1\e\\"
    fi
}

# Remove mode switching delay.
KEYTIMEOUT=5

function _set_block_cursor() { _set_cursor '\e[2 q' }
function _set_beam_cursor() { _set_cursor '\e[0 q' }

function zle-keymap-select {
  if [[ ${KEYMAP} == vicmd ]] || [[ $1 = 'block' ]]; then
      _set_block_cursor
  else
      _set_beam_cursor
  fi
}
zle -N zle-keymap-select
# ensure beam cursor when starting new terminal
precmd_functions+=(_set_beam_cursor) #
# ensure insert mode and beam cursor when exiting vim
zle-line-init() { zle -K viins; _set_beam_cursor }
zle-line-finish() { _set_block_cursor }
zle -N zle-line-finish