Как декодировать Base64, используя только ash в BusyBox?

Я подключился через SSH к серверу, и это последняя и единственная сессия, которая работает; если я выйду, я потеряю доступ к серверу навсегда.

Мне нужно передать файл (примерно 8 МБ), и я хотел бы сделать это, закодировав его в Base64 и вставив в терминал. Даже если существует лучшее решение, я всё равно хочу знать, как это сделать.

Как декодировать Base64, используя только ash? Команда base64 недоступна. Существует ли однострочный алгоритм для этого? Я использую среду BusyBox.

Используя код Awk, найденный здесь, вы можете легко декодировать его с помощью такой команды:

awk -f base64decode.awk [file1 [file2 [...]]] > output

Полная версия кода base64decode.awk приведена ниже:

# base64decode.awk
#
# Введение
# ========
# Декодирование строк, закодированных в Base64.
#
# Использование
# =============
# Обычно вы запускаете скрипт так:
#
#     $ awk -f base64decode.awk [file1 [file2 [...]]] > output

# Скрипт реализует декодирование Base64 на основе RFC 3548:
#
# https://tools.ietf.org/html/rfc3548

# создайте нашу таблицу поиска
BEGIN {
    # загрузить символы на основе алфавита
    for (i=0; i<26; i++) {
        BASE64[sprintf("%c", i+65)] = i
        BASE64[sprintf("%c", i+97)] = i+26
    }
    # загрузить наши цифры
    for (i=0; i<10; i++) {
        BASE64[sprintf("%c", i+48)] = i+52
    }
    # и наконец наши два дополнительных символа
    BASE64["+"] = 62
    BASE64["/"] = 63
    # также добавьте символ заполнения
    BASE64["="] = -1
}

# Основная функция для декодирования данных Base64.
#
# Аргументы:
# * encoded - строка Base64
# * result - массив для возврата двоичных данных
#
# Выходим при ошибке. Для других случаев использования это должно быть изменено на возврат кода ошибки.
function base64decode(encoded, result) {
    n = 1
    while (length(encoded) >= 4) {
        g0 = BASE64[substr(encoded, 1, 1)]
        g1 = BASE64[substr(encoded, 2, 1)]
        g2 = BASE64[substr(encoded, 3, 1)]
        g3 = BASE64[substr(encoded, 4, 1)]
        if (g0 == "") {
            printf("Неопознанный символ %c в строке, закодированной в Base 64\n",
            g0) >> "/dev/stderr"
            exit 1
        }
        if (g1 == "") {
            printf("Неопознанный символ %c в строке, закодированной в Base 64\n",
            g1) >> "/dev/stderr"
            exit 1
        }
        if (g2 == "") {
            printf("Неопознанный символ %c в строке, закодированной в Base 64\n",
            g2) >> "/dev/stderr"
            exit 1
        }
        if (g3 == "") {
            printf("Неопознанный символ %c в строке, закодированной в Base 64\n",
            g3) >> "/dev/stderr"
            exit 1
        }

        # в AWK нет побитового сдвига, но мы можем достичь тех же
        # результатов с помощью умножения, деления и арифметики по модулю
        result[n++] = (g0 * 4) + int(g1 / 16)
        if (g2 != -1) {
            result[n++] = ((g1 * 16) % 256) + int(g2 / 4)
            if (g3 != -1) {
                result[n++] = ((g2 * 64) % 256) + g3
            }
        }

        encoded = substr(encoded, 5)
    }
    if (length(encoded) != 0) {
        printf("Лишние символы в конце строки, закодированной в Base 64: \"%s\"\n",
        encoded) >> "/dev/stderr"
        exit 1
    }
}

# наша основная обработка текста
{
    # Декодировать полученные данные.
    base64decode($0, result)

    # Вывести декодированную строку.
    #
    # Мы не можем вывести символ NUL, используя BusyBox AWK. См.:
    # https://stackoverflow.com/a/32302711
    #
    # Поэтому мы собираем результат в восьмеричную строку и используем
    # команду оболочки "printf" для создания реального вывода.
    # 
    # Это также помогает в случае gawk, который путается с
    # не-ASCII выводом, если используется локализация, за исключением
    # случаев, когда установлено LC_ALL=C или "--characters-as-bytes".
    printf_str = ""
    for (i=1; i in result; i++) {
        printf_str = printf_str sprintf("\\%03o", result[i])
        if (length(printf_str) >= 1024) {
            system("printf '" printf_str "'")
            printf_str = ""
        }
        delete result[i]
    }
    system("printf '" printf_str "'")
}

_{код выше находится под лицензией GNU Affero General Public License v3.0}