Как я могу изменить сочетания клавиш для Firefox?

Я недавно начал использовать Firefox в качестве основного веб-браузера, и мне хотелось бы изменить некоторые настройки по умолчанию для сочетаний клавиш, особенно для переключения между вкладками. Можно ли это сделать?

Я заглянул в директорию Firefox в «Application Support», а также в сам пакет приложения, но ничего не нашел. Поиск в Google также не дал результатов.

Обновление: Я использую Firefox версии 3.6 на Mac OSX 10.6.2

Может быть, вы можете использовать расширение keyconfig для этого?

По этой ссылке некоторые люди говорят, что им удалось запустить это на Firefox 3:

@ M.C да, это так !!! (совместимо с
Firefox 3.6) вам нужно извлечь файл
“install.rdf” из
“functions_for_keyconfig-1.4.0.xpi”
с помощью программы разархивации, такой как “WinZip” в
Windows или “file roller” в Linux.

Отредактируйте
“install.rdf” и найдите эту строку:
“3.5.“.
Затем замените на
“3.6.“.

В “functions_for_keyconfig-1.4.0.xpi”
замените файл “install.rdf” на
измененный. Сохраните. Откройте ваш Firefox 3.6,
перетащите файл
“functions_for_keyconfig-1.4.0.xpi” в
окно Firefox. Это всё.

Переключитесь на левую или правую вкладку с помощью сочетаний клавиш:

Для Firefox 100+ (точнее, начиная с Firefox Quantum, выпущенного в 2017 году, когда добавления для переназначения сочетаний клавиш перестали работать)

вы можете переключаться на следующую или предыдущую вкладку, используя расширение, которое предоставляет вам жесты мыши, и использовать Autohotkey для управления жестами мыши, нажав клавишу на клавиатуре.

Например, вы можете установить добавление:
Gesturefy
https://addons.mozilla.org/en-US/firefox/addon/gesturefy/
или
Foxy Gestures
https://addons.mozilla.org/en-US/firefox/addon/foxy-gestures/

и настроить их, чтобы

• переключаться на правую вкладку, удерживая правую кнопку мыши и перетаскивая вправо,
• переключаться на левую вкладку, удерживая правую кнопку мыши и перетаскивая влево,

Затем установите Autohotkey и добавьте следующий код в файл скрипта автозагрузки Autohotkey.ahk:

    ;firefox
#IfWinActive, ahk_exe firefox.exe


    ;; use key for mouse gesture - Navigate to the Right Tab

f4::

;; use the function - show_Mouse(bShow := True)
show_Mouse(False)

;; Click and drag Right - Relative to the current mouse position


;; MouseClickDrag right, start X pos = 0, start Y pos = 0, End X pos = 20 (i.e. to the right), End Y pos 0, Speed = 0 -  i.e : в диапазоне: 0 (самый быстрый) до 100 (самый медленный) , R = относительный
MouseClickDrag right, 0, 0, 20, 0, 0, R
;;
;;
;; альтернативный вариант MouseClickDrag, используя SendEvent:
;;SendEvent "{Click 0 0 Down Right Relative}{click 20 0 Up Right Relative}"

;; переместить курсор мыши (влево) в исходное положение
MouseMove, -20, 0, 0, R

show_Mouse(True)

Return



    ;; use key for mouse gesture - Navigate to the Left Tab

f3::

;; use the function - show_Mouse(bShow := True)
show_Mouse(False)

;; Click and drag Left - Relative to the current mouse position


;; MouseClickDrag right, start X pos = 0, start Y pos = 0, End X pos = -20 (i.e. to the left), End Y pos 0, Speed = 0 -  i.e : в диапазоне: 0 (самый быстрый) до 100 (самый медленный) , R = относительный
MouseClickDrag right, 0, 0, -20, 0, 0, R
;;
;;
;; альтернативный вариант MouseClickDrag, используя SendEvent:
;;SendEvent "{Click 0 0 Down Left Relative}{click 20 0 Up Left Relative}"

;; переместить курсор мыши (вправо) в исходное положение
MouseMove, 20, 0, 0, R

show_Mouse(True)

Return

#If   ; КОНЕЦ для firefox.exe




;; функция для скрытия или отображения указателя мыши

;-------------------------------------------------------------------------------
show_Mouse(bShow := True) { ; показать/скрыть курсор мыши - источник: https://www.autohotkey.com/boards/viewtopic.php?f=6&t=37781
;-------------------------------------------------------------------------------
    ; WINAPI: SystemParametersInfo, CreateCursor, CopyImage, SetSystemCursor
    ; https://msdn.microsoft.com/en-us/library/windows/desktop/ms724947.aspx
    ; https://msdn.microsoft.com/en-us/library/windows/desktop/ms648385.aspx
    ; https://msdn.microsoft.com/en-us/library/windows/desktop/ms648031.aspx
    ; https://msdn.microsoft.com/en-us/library/windows/desktop/ms648395.aspx
    ;---------------------------------------------------------------------------
    static BlankCursor
    static CursorList := "32512, 32513, 32514, 32515, 32516, 32640, 32641"
        . ",32642, 32643, 32644, 32645, 32646, 32648, 32649, 32650, 32651"
    local ANDmask, XORmask, CursorHandle

    If bShow ; ярлык для отображения курсора мыши

        Return, DllCall("SystemParametersInfo"
            , "UInt", 0x57              ; UINT  uiAction    (SPI_SETCURSORS)
            , "UInt", 0                 ; UINT  uiParam
            , "Ptr",  0                 ; PVOID pvParam
            , "UInt", 0                 ; UINT  fWinIni
            , "Cdecl Int")              ; вернуть BOOL

    If Not BlankCursor { ; создать BlankCursor только один раз
        VarSetCapacity(ANDmask, 32 * 4, 0xFF)
        VarSetCapacity(XORmask, 32 * 4, 0x00)

        BlankCursor := DllCall("CreateCursor"
            , "Ptr", 0                  ; HINSTANCE  hInst
            , "Int", 0                  ; int        xHotSpot
            , "Int", 0                  ; int        yHotSpot
            , "Int", 32                 ; int        nWidth
            , "Int", 32                 ; int        nHeight
            , "Ptr", &ANDmask           ; const VOID *pvANDPlane
            , "Ptr", &XORmask           ; const VOID *pvXORPlane
            , "Cdecl Ptr")              ; вернуть HCURSOR
    }

    ; установить все системные курсоры в пустые, каждый требует новой копии
    Loop, Parse, CursorList, `,, %A_Space%
    {
        CursorHandle := DllCall("CopyImage"
            , "Ptr",  BlankCursor       ; HANDLE hImage
            , "UInt", 2                 ; UINT   uType      (IMAGE_CURSOR)
            , "Int",  0                 ; int    cxDesired
            , "Int",  0                 ; int    cyDesired
            , "UInt", 0                 ; UINT   fuFlags
            , "Cdecl Ptr")              ; вернуть HANDLE

        DllCall("SetSystemCursor"
            , "Ptr",  CursorHandle      ; HCURSOR hcur
            , "UInt", A_Loopfield       ; DWORD   id
            , "Cdecl Int")              ; вернуть BOOL
    }
}

Код скрывает перемещение мыши при нажатии клавиш, но вы можете убрать эту опцию (и функцию show_Mouse() тоже) и видеть, как курсор движется.

Код означает, что, когда вы нажимаете клавишу F3, вы переключаетесь на левую вкладку, а когда нажимаете клавишу F4, вы переключаетесь на правую вкладку, но мышь должна находиться внутри окна страницы, а не на меню или других кнопках, что легко осуществимо.

Внутри Autohotkey вы можете использовать кнопки мыши или команды прокрутки вверх или вниз вместо сочетаний клавиш.