Как поделиться демонстрацией контрольной системы, которую можно запустить простым копированием, вставкой и выполнением?

У меня есть очень простая программа ABAP, демонстрирующая, как отобразить поле текстового редактора (cl_gui_textedit), которую я хочу поделиться через Интернет, электронную почту, форум, блог или что-то другое.

Я хотел бы, чтобы люди просто скопировали, вставили и запустили эту очень простую демонстрацию мгновенно, но эта программа содержит статус GUI и экран Dynpro, которые сложно поделиться, потому что это не код (см. детали после кода программы).

Я знаю несколько способов делиться объектами ABAP и не ABAP, но на мой взгляд, это слишком сложно для такой простой демонстрации: запрос на транспорт SAP, репозиторий Git и abapGit.

Обратите внимание, что у меня есть и другие демонстрации Dynpro с использованием SAP Control Framework (cl_gui_alv_grid, cl_gui_html_viewer и т.д.), поэтому я хотел бы обобщить вопрос для всех типов контролов.

Существует ли способ легко поделиться, скопировать, вставить и запустить эту демонстрацию (возможно, переписав код), будь то cl_gui_textedit или любой другой контрол Dynpro?

3 элемента демонстрации:

• Программа:

  REPORT zdemo_cl_gui_textedit.
  DATA go_custom_container TYPE REF TO cl_gui_custom_container.
  DATA go_textedit TYPE REF TO cl_gui_textedit.
  
  START-OF-SELECTION.
    CALL SCREEN 100.
  
  MODULE _0100_pbo OUTPUT.
    SET PF-STATUS '0100'.
    IF go_textedit IS NOT BOUND.
      CREATE OBJECT go_custom_container
        EXPORTING
          container_name="CUSTOM_CONTAINER".
      CREATE OBJECT go_textedit
        EXPORTING
          parent  = go_custom_container.
    ENDIF.
  ENDMODULE.
  
  MODULE _0100_pai INPUT.
    IF sy-ucomm = 'EXIT'.
      SET SCREEN 0.
    ENDIF.
  ENDMODULE.
  

• Dynpro:
  • Элементы:
    • Поле CUSTOM_CONTAINER типа “Custom Control”.
  • Логика потока:

    PROCESS BEFORE OUTPUT.
      MODULE _0100_PBO.
    
    PROCESS AFTER INPUT.
      MODULE _0100_PAI AT EXIT-COMMAND.
    

• Статус GUI:
  • Кнопка EXIT, типа “E” (Команда выхода).

Мой предпочтительный способ предложить минимальный воспроизводимый пример (MRE) — использовать cl_gui_container=>screen0, который является контейнером, отображаемым поверх экрана Dynpro, и он может содержать любые виды контролов Dynpro (не ограничиваясь cl_gui_textedit).

Таким образом, сначала должен быть отображен экран Dynpro. Вместо общего экрана Dynpro можно использовать экран выбора, который строится с помощью операторов ABAP PARAMETERS или SELECT-OPTIONS.

В экранах выбора логика “Обработка перед выводом” соответствует событию “AT SELECTION-SCREEN OUTPUT”, а кнопка выхода управляется по умолчанию (если нужны другие кнопки, можно использовать контрол CL_GUI_TOOLBAR; несколько контролов могут быть отображены внутри cl_gui_container=>screen0, используя контрол CL_GUI_SPLITTER_CONTAINER).

Следовательно, весь пример можно упростить до следующих строк кода, объекты экрана Dynpro и статуса GUI не нужны.

REPORT zdemo_cl_gui_textedit.
DATA go_textedit TYPE REF TO cl_gui_textedit.
PARAMETERS dummy.
AT SELECTION-SCREEN OUTPUT.
  IF go_textedit IS NOT BOUND.
    go_textedit = NEW #( parent = cl_gui_container=>screen0 ).
  ENDIF.

NB: другие MRE на Stack Overflow, основанные на том же принципе:

• cl_salv_table
  • Может ли CL_SALV_TABLE отображать панель инструментов выше сетки, как это делает CL_GUI_ALV_GRID?
• cl_gui_alv_grid
  • Как вызвать код, когда пользователь нажимает на поле ALV hotspot?
  • Как прочитать изменения ALV после ввода пользователем?
• cl_gui_html_viewer
  • Как получить обновленную HTML радиокнопку в папке обработки рабочего процесса?
• cl_gui_toolbar
  • Обновить/освежить пользовательский контроль, чтобы отразить новые данные
• cl_salv_tree
  • Как поймать событие разворачивания узла в SALV Tree?

Обратите внимание, что демонстрация пользовательского интерфейса может быть улучшена, если она содержит богатые и значимые данные, которые можно получить из таблиц базы данных SFLIGHT, SBOOK и т.д. Например, эти данные могут быть использованы для сетки ALV. Эти таблицы должны быть присутствовать во всех системах ABAP, но могут быть доставлены пустыми. Чтобы сгенерировать содержимое, выполните любую из этих программ:

• Для SCARR, SPFLI, SFLIGHT, SBOOK…: запустите программу SAPBC_DATA_GENERATOR.
• Для таблиц, начинающихся с ALV_ (например, ALV_CHCK, ALV_T_T2), используемых несколькими демо-программами SAP: запустите программу BCALV_GENERATE_ALV_T_T2.