Как получить доменное имя в Windows с помощью команды?

Мне нужна аналогичная команда для domainname в Linux на Windows, без использования сторонних приложений.

Существует ли такая команда?

Попробуйте:

echo %USERDOMAIN%

или

echo %USERDNSDOMAIN%

Если это не работает, вы можете попробовать использовать systeminfo:

systeminfo | findstr /B /C:"Domain"

Вы можете запустить указанную ниже команду в командной строке, чтобы получить нужную информацию:

set user

Это дает нам гораздо больше информации, помимо имени домена (см. скриншот):

Список деталей, возвращаемых командой, приведен ниже:

1. User DNS Domain
2. User Domain
3. User Domain Roaming Profile
4. User Name
5. User Profile

Важное примечание: Домен, в котором зарегистрирован ваш компьютер, может не совпадать с доменом, в котором зарегистрирован пользователь. Рекомендуется изучить вопрос о транзитивности и направлении в доверительных отношениях доменов. Это поможет вам понять, как пользователь, зарегистрированный в одном домене, может войти на компьютер, зарегистрированный в другом домене.

Я просто хочу добавить свое решение на случай, если кому-то потребуется быстрый способ это сделать.

Мой подход заключается в использовании реестра для получения информации о домене:

reg query "HKLM\System\CurrentControlSet\Services\Tcpip\Parameters" /v "Domain"

%USERDOMAIN% и домен сетевого компьютера могут отличаться. Команда systeminfo даст правильный ответ, но она медленная! Вот решение, которое я использовал:

@REM + найти имя домена компьютера
 FOR /F "usebackq tokens=*" %%a IN (`ipconfig /all`) DO (
     @((ECHO %%a | findstr /i /c:"Primary Dns Suffix") && SET _str=%%a) > NUL 2>&1
 )
 FOR /F "tokens=2 delims=:" %%a IN ("%_str%") do SET _computerDomain=%%a
 SET _computerDomain=%_computerDomain: =%

 SET _fqdn=%COMPUTERNAME%.%_computerDomain%

@Mike: хорошее решение, но у меня были проблемы с ним в многоязычной среде.
У меня есть немецкие и английские серверы.

Я изменил ваш скрипт, чтобы использовать wmic.exe:

@REM + Найти имя домена компьютера
@echo off
FOR /F "usebackq tokens=*" %%a IN (`wmic.exe COMPUTERSYSTEM GET DOMAIN /Value`) DO (
      @((ECHO %%a | findstr /i /c:"Domain=") && SET _str=%%a) > NUL 2>&1
)
FOR /F "tokens=2 delims=^=" %%a IN ("%_str%") do SET _computerDomain=%%a
SET _computerDomain=%_computerDomain: =%
SET _fqdn=%COMPUTERNAME%.%_computerDomain%
echo %_fqdn%

Спасибо за вашу идею

Одной строки достаточно, чтобы получить домен с использованием локального пользователя:

FOR /F "usebackq tokens=2 delims==" %%a IN (`wmic.exe COMPUTERSYSTEM GET DOMAIN /Value ^|find /i "domain"`) DO set _computerDom=%%a

Большинство ответов здесь не совсем правы. Настройки, упомянутые выше, относятся к настроенному домену, однако это может быть не домен, в котором фактически находится компьютер. Домен меняется в зависимости от того, к чему подключен компьютер – одно подключение WiFi может идти к одному домену, а другое – к другому. Подключение через VPN добавит еще один домен. Во всех случаях показанное значение настроек в реестре, а также значения переменных окружения USERDOMAIN и USERDNSDOMAIN останутся неизменными.

Чтобы получить фактический домен, к которому подключен компьютер, используйте команду “ipconfig” в командной строке и проверьте значение “Connection-specific DNS Suffix”. Обратите внимание, например, что если вы отключите или деактивируете ваше соединение, это значение пропадет, указывая (верно), что вы больше не находитесь в домене.

На самом деле, компьютер может быть подключен к нескольким доменам одновременно, подключая несколько портов Ethernet, WiFi портов и т.д. к различным местам.

Чтобы предложить решения PowerShell:

Используя CIM (WMI):

# Только DNS-имя домена.
(Get-CimInstance Win32_ComputerSystem).Domain

# FQDN (полностью квалифицированное доменное имя, включая имя хоста)
$env:COMPUTERNAME + '.' + (Get-CimInstance Win32_ComputerSystem).Domain

Используя .NET, который также работает на платформах, отличных от Windows:

# Только DNS-имя домена.
[System.Net.Dns]::GetHostEntry('').HostName -replace '^[^.]+\.?'

# FQDN (полностью квалифицированное доменное имя, включая имя хоста)
[System.Net.Dns]::GetHostEntry('').HostName

Добавлю еще один способ для машины, добавленной в домен (не пользователя), используя ADSI (через .NET):

[System.DirectoryServices.ActiveDirectory.Domain]::GetComputerDomain().name