Как получить значение реестра и установить его в переменную в пакетном файле

Мне нужно получить значение из ключа реестра и сохранить его в переменной, используя пакетный файл.

Я написал базовую команду, чтобы проиллюстрировать свою логику (используя echo вместо установки переменной):

for /f "tokens=3 delims=    " %%a in ('reg query "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "LastUsedUsername" ^|findstr /ri "REG_SZ"') do echo=%%a

Я ожидаю, что имя пользователя будет выведено на экран, но этого не происходит.

Я уверен, что значение реестра “LastUsedUsername” не пустое, в нем действительно есть данные.
Кроме того, разделитель — это табуляция, а не пробелы.

РЕДАКТИРОВАТЬ

Если я просто набираю

reg query "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "LastUsedUsername"

… это возвращает:

HKEY_LOCAL_MACHINE\Software\Microsoft\Windows NT\CurrentVersion\Winlogon
    LastUsedUsername    REG_SZ    Администратор

Этот код

reg query "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "LastUsedUsername" ^| findstr /ri "REG_SZ"

… возвращает:

    LastUsedUsername    REG_SZ    Администратор

Затем, когда я использую команду for, я просто не получаю вывода от echo.

Вам не нужен переключатель delims вообще, поскольку по умолчанию используется пробел, который и возвращает reg query. Создавая bat-файл с этим циклом for и реестром на ключе, с которым я работаю, я получаю правильный echo, в моем случае значение “Red” цвета фона RGB равно 55:

for /f "tokens=3" %%a in ('reg query "HKCU\Control Panel\Colors"  /V Background  ^|findstr /ri "REG_SZ"') do echo %%a

Одобренный ответ не верен в некоторых ситуациях – если значение, прочитанное из реестра, содержит пробелы (Program Files (x86)), то возвращается только первая часть значения (‘Program’).
То, что я разработал, это:

FOR /F "tokens=2* skip=2" %%a in ('reg query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion" /v "CommonFilesDir"') do echo %%b

Результат C:\Program Files\Common Files

Синтаксис команды DOS верен. Я бы поставил под сомнение наличие у вас правильного значения ключа реестра. Просто введите часть req query… в командной строке и посмотрите, что она возвращает. Я использую Win 7, и я не нахожу ключа, LastUsedUsername, определенного в HKLM\Software\Microsoft\Windows NT\CurrentVersion\Winlogon

setx может сделать то, что вам нужно, без необходимости в скрипте:

setx DefaultUserName /k "HKEY_LOCAL_MACHINE\Software\Microsoft\Windows NT\CurrentVersion\Winlogon\DefaultUserName"

Примечание: Переменную нельзя использовать в текущем сценарии команды, так как она задается в окружении пользователя, а не в текущем окружении. Проверьте с помощью

echo %DefaultUserName% (не работает OOTB, но будет работать в новом окне cmd)
reg query "HKCU\Volatile Environment" /v "DefaultUserName" (не работает)
reg query "HKCU\Environment" /v "DefaultUserName" (работает)

Эта короткая процедура назначит тип и значение reg на: getkeytype/ getkeyvalue
и установит errorlevel и errror value, если не найдено, вот три примера использования:

@echo off
setlocal enableextensions enabledelayedexpansion & REM для получения значения var при exec с !varNm!

call :SUBGETKEY HKLM\SOFTWARE\Microsoft\nonExistantKey /v nothing
echo Err:%errorlevel%, Type:!getkeytype!, Value:!getkeyvalue!

call :SUBGETKEY "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "defaultUsername"
echo Err:%errorlevel%, Type:!getkeytype!, Value:!getkeyvalue!

call :SUBGETKEY "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "Shutdownflags"
echo Err:%errorlevel%, Type:!getkeytype!, Value:!getkeyvalue!

pause

goto :FIN

:SUBGETKEY
  set SubKeyParam= %*&  rem получить параметры, добавить пробел, чтобы не было пустоты
  REM запрос GETKEY, возвращает: getkeytype, getkeyvalue
  rem если не найдено: errorlevel установлен, и "error" на переменных
  set getkeyaux=error error&  REM значения возвращаемых значений по умолчанию не найдены
  FOR /F "tokens=2* delims=_" %%A IN ('REG.EXE QUERY %SubKeyParam% 2^>nul') DO (
    set getkeyaux=REG_%%A%%B
  )
  rem echo -%errorlevel%-!getkeyaux!-
  for /f "tokens=1*" %%I in ("!getkeyaux!") do (
    set getkeytype=%%I
    set getkeyvalue=%%J
  ) & rem {call} устанавливает ERROLEVEL 1, иначе {call } устанавливает ERROLEVEL 0
     if %getkeytype%==error (CALL) else (CALL )
  goto :FIN

:FIN