Как удалить созданные вручную элементы управления номерами страниц с помощью VBA?

Я собираюсь создать шаблон для строк, таких как Pg. 125 или Pg. 397, и полагал, что это будет Pg\. ([0-9]{1,3}).

У меня есть документ, в который я вручную вставил различные номера страниц, и числовая часть является простым текстовым управлением содержимым:

Проблема, с которой я сталкиваюсь, заключается в том, что когда я использую модуль поиска и замены со строкой, он не захватывает её. Он захватывает Pg. и ([0-9]{1,3}) отдельно, но не вместе.

В конечном итоге цель состоит в том, чтобы создать макрос VBA, который сбросит номера страниц к их оригинальным текстам-заполнителям и удалит текущие значения, чтобы я мог перенумеровать страницы, когда обновлю шаблон.

Ниже представлен код, который я пытался использовать, но не был успешен:

Sub FindAndEraseValue()
    Dim rng As Range
    Dim pattern As String
    pattern = "Pg. [0-9]{1,3}"
    
    ' Начнем с начала документа
    Set rng = ActiveDocument.Content
    
    With rng.Find
        .ClearFormatting
        .Text = "Pg. [0-9]{1,3}"
        .MatchWildcards = True

        ' Цикл для поиска всех вхождений
        Do While .Execute
            ' Установите диапазон на найденный текст
            Set rng = rng.Duplicate

            ' Определите часть, которую нужно сохранить (часть "Pg.")
            If rng.Text Like "Pg. [0-9]{1,3}" Then
                ' Замените числа на пустую строку
                rng.Text = "Pg. "
            End If
        Loop
    End With
End Sub

Я думаю, что нечто подобное должно сработать:

Sub trickymatch()
Dim r As Word.Range
Dim ccrange As Word.Range
Set r = ActiveDocument.Range
With r.Find
  .ClearFormatting
  .Text = "[0-9]{1,3}"
  .MatchWildcards = True
  Do
    .Execute Forward:=True, Wrap:=wdFindStop
    If .Found Then
      If r.Information(wdInContentControl) Then
        If ActiveDocument.Range(r.Start - 5, r.Start - 1).Text = "Pg. " Then
          Set ccrange = ActiveDocument.Range(r.Start - 1, r.Start).ContentControls(1).Range
          If ccrange = r Then
            r.Text = ""
          End If
          Set ccrange = Nothing
        End If
      End If
    End If
  Loop Until Not .Found
End With
End Sub

Совпадение с использованием подстановочных знаков является проблемой, потому что начало и конец управления содержимым представлены нулевыми символами, и это останавливает процесс сопоставления шаблона от совпадения полного шаблона Pg. [0-9]{1,3}.

Вы можете это увидеть, если выберете, скажем, Pg. 137 в вашем текстовом примере и используете VBA, чтобы посмотреть на Selection.Text и Selection.Characters.

Selection.Text будет Pg. 137, как и ожидалось, а Len(Selection.Text) будет 7.

Но Selection.Characters.Count будет либо 8, либо 9 (в зависимости от того, выбрали ли вы конец управления содержимым или нет). Символы с 1 по 4 будут Pg. , а с 6 по 8 будут 137, но если вы попытаетесь посмотреть на AscW(Selection.Characters(5)), вы увидите ошибку.

Если вы попробуете:

Dim s As String
s = Selection.Characters(5)
Debug.Print Len(s)

Вы, как я думаю, увидите 0. s фактически соответствует vbNullString (а не vbNullChar, что технически отличается).

Кроме того, оператор VBA Like позволяет использовать некоторые подстановочные знаки, но не конструкцию {1,3}, которая у вас в коде.

Так что цель моего кода — искать числовые строки длиной до 3 цифр. Если одна найдена, убедитесь, что она находится в управлении содержимым и предшествует Pg. . Если так, убедитесь, что числовая строка имеет такую же длину, как и содержимое управления содержимым (в противном случае это может быть на самом деле строка из 4 цифр, например). Если так, установите строку на “”).

Это всего лишь быстрая попытка решения. Но в зависимости от вашего текста может быть проще искать текст Pg. и искать следующее управление содержимым.