Клонирование виртуальной машины UTM – IP-адрес такой же?

Может кто-то подскажет, как настроить IP-адрес клонов ВМ с UTM?

Когда я создаю новую ВМ UTM, IP-адрес отличается. Это нормально.

Когда я клонирую существующую ВМ UTM, IP-адрес такой же, как у клона.

Мой вопрос: с чего начать, чтобы клону был назначен собственный IP?

Примечание – я использую共享ную сеть. И я использую Ubuntu.

Выключите ВМ и перейдите в её настройки>сеть, нажмите на Случайный в MAC-адресе, включите ВМ, и вы увидите, что у неё должен быть новый IP

Если вы хотите клонировать виртуальные машины с помощью скрипта, вы можете использовать интерфейс UTM AppleScript, чтобы установить новый случайный MAC-адрес. Вот пример Bash-скрипта:

#!/bin/bash

VM_NAME="my_virtual_machine"

# Создайте клон ВМ
utmctl clone "${VM_NAME}" --name "${VM_NAME}-clone"

# Случайный MAC-адрес
# (установка пустой строки говорит UTM сгенерировать случайный MAC) 
osascript <<END
tell application "UTM"
    set vm to virtual machine named "${VM_NAME}-clone"
    set config to configuration of vm
    set item 1 of network interfaces of config to {address:""}
    update configuration of vm with config
end tell
END

Часть AppleScript работает только если одному ВМ назначен один сетевой интерфейс.

Смотрите https://docs.getutm.app/scripting/cheat-sheet/#configuration как справочный материал.

Спасибо за ответы, как решение через интерфейс, так и скрипт работают для получения другого IP. Я использовал этот подход в нашем плагине UTM Vagrant, чтобы убедиться, что ВМ, запущенные из одной и той же коробки vagrant, будут иметь разные IP.

Однако я хочу предупредить вас о Apple-скрипте от @IngoMeyer.
Скрипт обновит всю конфигурацию сетевого интерфейса.
Пример: если элемент 1 сетевых интерфейсов это ‘Эмулируемый VLAN’, он превратится в новый интерфейс ‘Общая сеть’, который является значением по умолчанию, если режим не указан при создании интерфейса.
Передача пустой строки для обновления просто обновит его как пустую строку в конфигурации UTM и приведет к ошибке qemu при запуске ВМ.

Поэтому я в конечном итоге написал функцию для генерации случайного MAC-адреса (похожую на то, что делает кнопка ‘Случайный’ в UTM) и затем передал его в мой AppleScript.

set_mac_address.applescript

# Этот скрипт устанавливает MAC-адрес сетевого интерфейса в определенной виртуальной машине UTM.
# Использование: osascript set_mac_address.applescript <VM_UUID> <NIC_INDEX> <MAC_ADDRESS>
# Пример: osascript set_mac_address.applescript A123 1 XX:XX:XX:XX:XX:XX
on run argv
  set vmID to item 1 of argv
  set nicIndex to item 2 of argv
  set macAddress to item 3 of argv

  tell application "UTM"
    set vm to virtual machine id vmID
    set config to configuration of vm
    set networkInterfaces to network interfaces of config

    repeat with anInterface in networkInterfaces
      if nicIndex as integer is index of anInterface then
        -- Установите предоставленный MAC-адрес
        set address of anInterface to macAddress
      end if
    end repeat

    -- Обновите конфигурацию ВМ
    update configuration of vm with config
  end tell
  
end run

Использование:
osascript set_mac_address.applescript DF1241A1-102A-41DD-AE2A-BD51F8749A00 0 46:ED:B9:1F:55:A4

Если вы хотите управлять ВМ UTM с помощью Vagrant, посмотрите плагин https://naveenrajm7.github.io/vagrant_utm/