Почему в моей дистрибуции на базе Linux Yocto не установлен файл sysctl.conf?

На моей Yocto-базированной дистрибуции Linux я не нахожу файл sysctl.conf. Доказательством этого является выполнение команды:

> find / -name "sysctl.conf"

которая имеет пустой вывод.

На моей сборочной системе Yocto я могу найти:

1. файл sysctl.conf по пути: meta/recipes-extended/procps/procps/
2. рецепт procps_3.3.16.bb по пути meta/recipes-extended/procps/

Содержимое рецепта procps_3.3.16.bb следующее:

SUMMARY = "System and process monitoring utilities"
DESCRIPTION = "Procps содержит набор системных утилит, которые предоставляют системную информацию о процессах, используя \
файловую систему /proc. Пакет включает программы ps, top, vmstat, w, kill и skill."
HOMEPAGE = "https://gitlab.com/procps-ng/procps"
SECTION = "base"
LICENSE = "GPLv2+ & LGPLv2+"
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
                    file://COPYING.LIB;md5=4cf66a4984120007c9881cc871cf49db \
                    "

DEPENDS = "ncurses"

inherit autotools gettext pkgconfig update-alternatives

SRC_URI = "git://gitlab.com/procps-ng/procps.git;protocol=https \
           file://sysctl.conf \
           "
SRCREV = "59c88e18f29000ceaf7e5f98181b07be443cf12f"

S = "${WORKDIR}/git"

# В исходной версии есть собственный autogen.sh, который вызывает po/update-potfiles, так как они
# не предоставляют по/POTFILES.in (что глупо). Без этого файла gettext
# не считает по/ папкой gettext и не создает по/Makefile.
do_configure_prepend() {
    ( cd ${S} && po/update-potfiles )
}

EXTRA_OECONF = "--enable-skill --disable-modern-top"

PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
PACKAGECONFIG[systemd] = "--with-systemd,--without-systemd,systemd"

do_install_append () {
    install -d ${D}${base_bindir}
    [ "${bindir}" != "${base_bindir}" ] && for i in ${base_bindir_progs}; do mv ${D}${bindir}/$i ${D}${base_bindir}/$i; done
    install -d ${D}${base_sbindir}
    [ "${sbindir}" != "${base_sbindir}" ] && for i in ${base_sbindir_progs}; do mv ${D}${sbindir}/$i ${D}${base_sbindir}/$i; done
        if [ "${base_sbindir}" != "${sbindir}" ]; then
                rmdir ${D}${sbindir}
        fi

        install -d ${D}${sysconfdir}
        install -m 0644 ${WORKDIR}/sysctl.conf ${D}${sysconfdir}/sysctl.conf
        if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
                install -d ${D}${sysconfdir}/sysctl.d
                ln -sf ../sysctl.conf ${D}${sysconfdir}/sysctl.d/99-sysctl.conf
        fi
}

CONFFILES_${PN} = "${sysconfdir}/sysctl.conf"

bindir_progs = "free pkill pmap pgrep pwdx skill snice top uptime w"
base_bindir_progs += "kill pidof ps watch"
base_sbindir_progs += "sysctl"

ALTERNATIVE_PRIORITY = "200"
ALTERNATIVE_PRIORITY[pidof] = "150"

ALTERNATIVE_${PN} = "${bindir_progs} ${base_bindir_progs} ${base_sbindir_progs}"

ALTERNATIVE_${PN}-doc = "kill.1 uptime.1"
ALTERNATIVE_LINK_NAME[kill.1] = "${mandir}/man1/kill.1"
ALTERNATIVE_LINK_NAME[uptime.1] = "${mandir}/man1/uptime.1"

python __anonymous() {
    for prog in d.getVar('base_bindir_progs').split():
        d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_bindir'), prog))

    for prog in d.getVar('base_sbindir_progs').split():
        d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_sbindir'), prog))
}

# 'ps' не подходит для использования в качестве инструмента безопасности, поэтому помещаем в белый список этот CVE.
# https://bugzilla.redhat.com/show_bug.cgi?id=1575473#c3
CVE_CHECK_WHITELIST += "CVE-2018-1121"

С предыдущим рецептом procps_3.3.16.bb я думаю, что файл sysctl.conf должен быть установлен в /etc/; я думаю так, потому что в функции do_install_append(), объявленной в рецепте, присутствует команда:

install -m 0644 ${WORKDIR}/sysctl.conf ${D}${sysconfdir}/sysctl.conf

которая, кажется, устанавливает файл sysctl.conf в образе.

Кроме того, после выполнения команды bitbake procps, в папке сборки procps я могу найти файл /etc/sysctl.conf в подкаталогах image и package.

Таким образом, кажется, что файл правильно подготовлен для развертывания на конечное изображение, но развертывание не выполняется.

Вопрос

Почему файл sysctl.conf отсутствует в папке /etc/ файловой системы образа yocto?