Проверка только числового ввода в пакетном файле

В командной строке, основанной на Windows NT (в основном для XP или выше), есть ли способ проверить, является ли переданный параметр только числом? В зависимости от числа, я хочу, чтобы он выполнял код x раз.

Отредактировано, чтобы исправить регулярное выражение согласно комментарию debham. Оказалось, что добавление пробела перед символом трубы после echo добавляет пробел к строке, что нарушало сопоставление начала и конца строки. Регулярное выражение можно улучшить, исключив пробелы в начале и в конце.

Есть команда findstr. Она может искать файлы с помощью регулярных выражений, подобно grep в Linux. Она также может искать переданные на вход данные.

@echo off

set param=%1

echo %param%| findstr /r "^[1-9][0-9]*$">nul

if %errorlevel% equ 0 (
    echo Valid number
)

Объяснение

Параметр устанавливается в переменную param. Однако ничто не мешает вам использовать параметр напрямую (%1 для первого параметра).

findstr используется для поиска в переданном на вход потоке с флагом /r для регулярного выражения.

Шаблон:

• ^ означает начало строки.

• [0-9] означает цифру. * означает предыдущее повторенное ноль или более раз. Таким образом, [0-9][0-9]* означает одну цифру плюс ноль или более цифр. Другими словами, по крайней мере, одну цифру. + одно или более раз, кажется, не поддерживается findstr. Учтите, что [1-9] используется для первой цифры, чтобы исключить нули в начале – см. комментарии.

• $ означает конец строки.

Теперь, цикл в батч-файле, выполняющий x раз… если x не является допустимым числом, цикл вообще не выполняется — он просто пропускается для следующей строки. Поэтому нет необходимости проверять, является ли вводимое значение допустимым числом!

@echo off

set param=%1

for /l %%a in (1,1,%param%) do (
    echo %%a
)

Цикл выполняется с использованием for /l, где (x,y,z) означает начать с x, увеличивать на y, пока z не будет достигнуто. И он устанавливает %%a в текущее число/итерацию.

Примечание: это фактически не работает, если есть начальний ноль, приводя командный процессор к интерпретации его как восьмеричного числа. См. ответ dbenham для более лучшего решения.

Следующее работает очень хорошо для меня. SET /a param=%1+0 всегда возвращает 0, если %1 пусто или не является числом. В противном случае он возвращает переданное число.

SET /a param=%1+0
IF NOT %param%==0 ECHO Valid number

Это определит, является ли первый параметр допустимым натуральным числом (неотрицательным целым числом).

@echo off
echo %1|findstr /xr "[1-9][0-9]* 0" >nul && (
  echo %1 is a valid number
) || (
  echo %1 is NOT a valid number
)

Если вы хотите разрешить кавычки вокруг числа, то

@echo off
echo "%~1"|findstr /xr /c:\"[1-9][0-9]*\" /c:\"0\" >nul && (
  echo %~1 is a valid number
) || (
  echo %~1 is NOT a valid number
)

Примечание — начальные нули запрещены, потому что батч обрабатывает их как восьмеричные, так что значение вроде 09 недопустимо, а 010 имеет значение 8.

Вдохновлено превосходным ответом Боба с добавлением следующих улучшений

• Исправление логики errorlevel
• Реализация цикла DoWork, который проходит по числу и выполняет некоторую арифметику

:::::::::::::::
::CountTo.bat
:::::::::::::::
@echo off

::Это число для проверки
if "%1"=="" goto :Usage

set param=%1
set matchPattern="^[1-9][0-9]*$"

::проверка, соответствует ли param шаблону matchPattern, без вывода
:: (перенаправление stdout в nul, и stderr в stdout)

echo %param%|findstr /r %matchPattern%>nul 2>&1

:: проверка code errorlevel 1 или выше. errorlevel 0 обрабатывается как
:: падение без проверки
if errorlevel 1 goto :MyHandleErrorCode

::Успех (errorlevel ! >= 1) так что продолжаем.
echo %param% is a valid number
echo  (совпадает с findstr /r %param% %matchPattern%)
echo  findstr вернул errorlevel 0

::любой другой код, который должен выполняться в батч-файле, располагается  
echo.
echo Итерация с 1 до %param%
echo.
for /l %%i in (1,1,%param%) do call :DoWork %%i

::что-то еще,
:: .
:: .

::очистка
:: .
:: .

::выход из батч-файла здесь, пропуская встраиваемые подпрограммы
goto :eof

:::::::::::::::::::::::::
:: Основная рабочая подпрограмма
:::::::::::::::::::::::::
:DoWork
set /a offset = %1 - 1
set /a square = %1 * %1
echo элемент %1
echo   смещение: %offset%
echo   квадрат: %square%
echo.
goto :eof

:::::::::::::::::::::::
:: Код обработки ошибок
:::::::::::::::::::::::
:MyHandleErrorCode
echo.
echo CountTo %param%
echo   %param% не является допустимым числом
echo   (не совпадает с findstr /r %param% %matchPattern%)
echo   findstr вернул errorlevel ^>= 1
:: код ошибки не имеет goto :eof, мы хотим упасть в :Usage

::::::::
:Usage
::::::::
echo.
echo Usage:
echo.   CountTo ^<someNumber^>

Проблема с следующим в том, что он всегда возвращает ‘Valid number’, потому что ‘if errorlevel 0’ всегда истинно, так как это сравнение ‘>= 0’, а не ‘== 0’.

@echo off

set param=%1

echo %param%| findstr /r "^[1-9][0-9]*$">nul

if errorlevel 0 (
    echo Valid number
)

мои 2 копейки

Вы можете проверить любую переменную, является ли она числом:

SET "var="&for /f "delims=0123456789" %i in ("%a") do set var=%i
if defined var (echo."NIC">nul) else (echo."number")

set xx=33
echo %xx%
SET /a %xx%+0 2>nul >nul && echo all Digits

set xx=3x3
echo %xx%
SET /a %xx%+0 2>nul >nul || echo No Digits

Я не знаю, почему, но в моей системе команда findstr не работала. Уровень ошибок не изменялся на совпадении или несопадении.

Я придумал другой метод

:: Найти все цифры. Проанализировать строку и использовать все цифры в качестве
:: разделителей. Если вся строка — цифра, то мы получим пустое
:: значение.
SET ALL_DIGITS=0
FOR /F "tokens=* delims=0123456789" %%a IN ("%VALUE%") DO (
    IF "[%%a]" EQU "[]" SET ALL_DIGITS=1
)

IF %ALL_DIGITS% EQU 0 (
    ECHO ERROR: %VALUE% is not all numbers
)

Один подход:

set test_var=001
( 
  (if errorlevel %test_var% break ) 2>nul
)&&(
  echo %test_var% is numeric
)||(
  echo %test_var% is NOT numeric
)

set test_var=001X
( 
  (if errorlevel %test_var% break ) 2>nul
)&&(
  echo %test_var% is numeric
)||(
  echo %test_var% is NOT numeric
)

Другой:

@echo off 

:isInterer  input [returnVar] 
setlocal enableDelayedexpansion 
set "input=%~1" 

if "!input:~0,1!" equ "-" (
    set "input=!input:~1!"
) else (
    if "!input:~0,1!" equ "+" set "input=!input:~1!"
)

for %%# in (1 2 3 4 5 6 7 8 9 0) do ( 
        if not "!input!" == "" ( 
                set "input=!input:%%#=!" 
    )         
) 

if "!input!" equ "" ( 
        set result=true 
) else ( 
        set result=false 
) 

endlocal & if "%~2" neq "" (set %~2=%result%) else echo %result% 

Однострочная подпрограмма для получения допустимого числа из любого ввода, возвращаемое число на errorlevel, гораздо быстрее, чем вызов findStr, возвращает 0, если не действителен (не всегда 0, нужно проверять подробнее), выведет “случайное” при выходе за пределы диапазона longInt:

@echo off
set x=*non987digits987start987returns0*
call :GetNum %x%
echo %errorlevel%

set x=123first987digits987returned
call :GetNum %x%
echo %errorlevel%
pause
goto :eof

:GetNum
exit /b %1

:main 
set /p input=text
if %input% equ 0 goto valid
set /a inputval="%input%"*1
if %inputval% equ 0 goto invalid
goto valid

:invalid
echo Input is not an integer.

:valid
echo Input is an integer.

Вот игра, использующая эту функцию.

@echo off
:main
set /a guessmin=1
set /a guessmax=100
set /a guessrand=%random% %%100 +1
echo.
:check
if %guessmin% equ %guessmax% goto fail
set /p input=- Pick a number %guessmin% - %guessmax%: 
set /a inputval="%input%"*1
if %inputval% equ 0 goto invalid
if %inputval% gtr %guessmax% goto invalid
if %inputval% lss %guessmin% goto invalid
if %inputval% gtr %guessrand% goto high
if %inputval% lss %guessrand% goto low
if %inputval% equ %guessrand% goto mid
:invalid
echo   Пожалуйста, введите действительное значение.
echo.
goto check
:high
echo   Ваше предположение было слишком высоким.
echo.
set /a guessmax=%inputval%-1
goto check
:low
echo   Ваше предположение было слишком низким.
echo.
set /a guessmin=%inputval%+1
goto check
:mid
echo   Ваше предположение было верным. Игра сейчас перезагрузится.
set /p input=- Нажмите Enter, чтобы сыграть снова.
cls
goto main
:fail
echo   Вы действительно умудрились проиграть, потому что осталось только
echo   одно число. Это число %guessrand%.
set /p input=- Нажмите Enter, чтобы снова проиграть.
cls
goto main