В моей дистрибутивной сборке Linux на базе Yocto файл sysctl.conf не установлен рецептом procps.

На моей Linux-распределении на основе Yocto я не нахожу файл sysctl.conf. Доказательство этого — выполнение команды:

> find / -name "sysctl.conf"

которая дает пустой вывод.

На моей системе сборки Yocto (я использую релиз zeus) я могу найти:

1. файл sysctl.conf по пути: meta/recipes-extended/procps/procps/
2. рецепт procps_3.3.16.bb по пути meta/recipes-extended/procps/

Содержание рецепта procps_3.3.16.bb следующее:

SUMMARY = "Системные и процессные утилиты мониторинга"
DESCRIPTION = "Procps содержит набор системных утилит, которые предоставляют системную информацию о процессах, используя \
файловую систему /proc. Пакет включает в себя программы: ps, top, vmstat, w, kill и skill."
HOMEPAGE = "https://gitlab.com/procps-ng/procps"
SECTION = "base"
LICENSE = "GPLv2+ & LGPLv2+"
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
                    file://COPYING.LIB;md5=4cf66a4984120007c9881cc871cf49db \
                    "

DEPENDS = "ncurses"

inherit autotools gettext pkgconfig update-alternatives

SRC_URI = "git://gitlab.com/procps-ng/procps.git;protocol=https \
           file://sysctl.conf \
           "
SRCREV = "59c88e18f29000ceaf7e5f98181b07be443cf12f"

S = "${WORKDIR}/git"

# Upstream имеет пользовательский autogen.sh, который вызывает po/update-potfiles, так как
# они не предоставляют po/POTFILES.in (что глупо). Без этого файла gettext
# не считает po/ директорию gettext и не будет генерировать po/Makefile.
do_configure_prepend() {
    ( cd ${S} && po/update-potfiles )
}

EXTRA_OECONF = "--enable-skill --disable-modern-top"

PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
PACKAGECONFIG[systemd] = "--with-systemd,--without-systemd,systemd"

do_install_append () {
    install -d ${D}${base_bindir}
    [ "${bindir}" != "${base_bindir}" ] && for i in ${base_bindir_progs}; do mv ${D}${bindir}/$i ${D}${base_bindir}/$i; done
    install -d ${D}${base_sbindir}
    [ "${sbindir}" != "${base_sbindir}" ] && for i in ${base_sbindir_progs}; do mv ${D}${sbindir}/$i ${D}${base_sbindir}/$i; done
        if [ "${base_sbindir}" != "${sbindir}" ]; then
                rmdir ${D}${sbindir}
        fi

        install -d ${D}${sysconfdir}
        install -m 0644 ${WORKDIR}/sysctl.conf ${D}${sysconfdir}/sysctl.conf
        if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
                install -d ${D}${sysconfdir}/sysctl.d
                ln -sf ../sysctl.conf ${D}${sysconfdir}/sysctl.d/99-sysctl.conf
        fi
}

CONFFILES_${PN} = "${sysconfdir}/sysctl.conf"

bindir_progs = "free pkill pmap pgrep pwdx skill snice top uptime w"
base_bindir_progs += "kill pidof ps watch"
base_sbindir_progs += "sysctl"

ALTERNATIVE_PRIORITY = "200"
ALTERNATIVE_PRIORITY[pidof] = "150"

ALTERNATIVE_${PN} = "${bindir_progs} ${base_bindir_progs} ${base_sbindir_progs}"

ALTERNATIVE_${PN}-doc = "kill.1 uptime.1"
ALTERNATIVE_LINK_NAME[kill.1] = "${mandir}/man1/kill.1"
ALTERNATIVE_LINK_NAME[uptime.1] = "${mandir}/man1/uptime.1"

python __anonymous() {
    for prog in d.getVar('base_bindir_progs').split():
        d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_bindir'), prog))

    for prog in d.getVar('base_sbindir_progs').split():
        d.setVarFlag('ALTERNATIVE_LINK_NAME', prog, '%s/%s' % (d.getVar('base_sbindir'), prog))
}

# 'ps' не подходит для использования в качестве инструмента безопасности, поэтому в белом списке этот CVE.
# https://bugzilla.redhat.com/show_bug.cgi?id=1575473#c3
CVE_CHECK_WHITELIST += "CVE-2018-1121"

С предыдущим рецептом procps_3.3.16.bb я думаю, что файл sysctl.conf должен быть установлен в /etc/; я думаю так, потому что в функции do_install_append(), объявленной в предыдущем рецепте, присутствует команда:

install -m 0644 ${WORKDIR}/sysctl.conf ${D}${sysconfdir}/sysctl.conf

которая, кажется, устанавливает файл sysctl.conf в путь /etc файловой системы образа, созданного bitbake.

Более того, вывод выполнения команды bitbake procps сохраняется в папке сборки procps и в этом выводе, файл /etc/sysctl.conf находится в обоих подкаталогах image и package.
Таким образом, кажется, что файл правильно подготовлен для развертывания в окончательный образ, но развертывание не выполнено.

На моей системе используется systemd-sysctl

По этой ссылке я нашел следующую фразу:

Эта страница руководства описывает конфигурационные файлы для procps sysctl.
Если вы используете systemd-sysctl(8), обратитесь к sysctl.d(5) и обратите внимание,
что он не будет использовать файл /etc/sysctl.conf.

Это означает, что /etc/sysctl.conf не используется на моей системе.

Ссылки по той же теме

1. Очень полезна эта ссылка, которая говорит о том же аргументе, но в случае, когда файл sysctl.conf развертывается и, следовательно, присутствует в файловой системе Yocto.

2. Моя точная проблема найдена в этой другой ссылке, но я попробовал следовать всем предложенным в ней рекомендациям безуспешно.

3. Эта другая ссылка посвящена рецепту pocps_3.3.16.bb.

Вопрос

С учетом вышеописанной конфигурации, почему файл sysctl.conf не развертывается в папку /etc/ в файловой системе yocto образа?